How to create a folder with name as current date in batch (.bat) files

Question

I don't know much about windows .bat file syntax. My simple requirement is to create a folder at a specific location with name as current date. I tried searching this on google but didn't get any good option. Is there any way to do this?

Answer 1

mkdir %date:~-4,4%%date:~-10,2%%date:~7,2%

Answer 2

Quick and dirty: If you can live with the date being UTC instead of local, you can use:

for /f "skip=1" %%d in ('wmic os get localdatetime') do if not defined mydate set mydate=%%d
md %mydate:~0,8%

Works in all locales. Only on XP and higher, though.

Answer 3

Try this (an equivalent of bash backquotes):

for /f "tokens=1* delims=" %%a in ('date /T') do set datestr=%%a
mkdir %datestr%

For further information, see http://ss64.com/nt/for_cmd.html

Answer 4

You need to get rid of the '/' characters in the date before you can use it in mkdir like this:

setlocal enableextensions
set name=%DATE:/=_%
mkdir %name%

Answer 5

If you want mm-dd-yyyy format you can use:

mkdir %date:~-10,2%"-"%date:~7,2%"-"%date:~-4,4%

Answer 6

This depends on the regional settings of the computer, so first check the output of the date using the command prompt or by doing an echo of date.

To do so, create a batch file and add the below content

echo %date%    
pause

---

It produces an output, in my case it shows Fri 05/06/2015.

Now we need to get rid of the slash (/)

For that include the below code in the batch file.

set temp=%DATE:/=%

if you echo the "temp", you can see the date without the slash in it.

---

Now all you need to do is formatting the date in the way you want.

For example I need the date in the format of YYYYMMDD, then I need to set the dirname as below

To explain how this works, we need to compare the value of temp

Fri 05062015.

now position each characters with numbers starting with 0.

Fri 0506201 5

01234567891011

So for the date format which I need is 20150605,

The Year 2015, in which 2 is in the 8th position, so from 8th position till 4 places, it will make 2015.

The month 06, in which 0 is in the 6th position, so from 6th position till 2 places, it will make 06.

The day 05, in which 0 is in the 4th position, so from 4th position till 2 places, it will make 05.

So finally to set up the final format, we have the below.

SET dirname="%temp:~8,4%%temp:~6,2%%temp:~4,2%"

To enhance this date format with "-" or "_" in between the date, month and year , you can modify with below

SET dirname="%temp:~8,4%-%temp:~6,2%-%temp:~4,2%"

or

SET dirname="%temp:~8,4%_%temp:~6,2%_%temp:~4,2%"

So the final batch code will be

======================================================

@echo off    
set temp=%DATE:/=%
set dirname="%temp:~8,4%%temp:~6,2%%temp:~4,2%"
mkdir %dirname%

======================================================

The directory will be created at the place where this batch executes.

Answer 7

echo var D = new Date() > tmp.js 
echo D = (D.getFullYear()*100+D.getMonth()+1)*100+D.getDate() >> tmp.js 
echo WScript.Echo( 'set YYYYMMDD='+D ) >> tmp.js 
echo @echo off > tmp.bat 
cscript //nologo tmp.js >> tmp.bat 
call tmp.bat
mkdir %YYYYMMDD%

Answer 8

for /F “tokens=1-4 delims=/ ” %%A in (‘date /t’) do (
    set DateDay=%%A
    set DateMonth=%%B
    set DateYear=%%C
)
set CurrentDate=%DateDay%-%DateMonth%-%DateYear%
md %CurrentDate%

This will give you a newly created folder with today’s date, in the format of DD-MM-YY

Sourced from: Ali's Knowledge Base

Answer 9

I had a problem with this because my server ABSOLUTELY had to have its date in MM/dd/yyyy format, while I wanted the directory to be in YYYY-MM-DD format for neatness sake. Here's how to get it in YYYY-MM-DD format, no matter what your regional settings are set as.

Find out what gets displayed when you use %DATE%:

From a command prompt type:

ECHO %DATE%

Mine came out 03/06/2013 (as in 6th March 2013)

Therefore, to get a directory name as 2013-03-06, code this into your batch file:

SET dirname="%date:~6,4%-%date:~0,2%-%date:~3,2%"
mkdir %dirname%

Answer 10

This should work:

mkdir %date%

If it doesn't, try this:

setlocal enableextensions
mkdir %date%

Answer 11

I am sitting in exactly the same boat as you as soon as i am AM before 10 i cannot use the below, i have set my time from 12hr to 24 hr, changed hh/mm to HH/mm I have tried most of the codes i could find. below will help at least a little. tweak and fix :)

Below may help also

set DD=%DATE:~0,2%

set MM=%DATE:~3,2%

set YY=%DATE:~8,2%

set YYYY=%DATE:~6,4%

set hh=%hh: =0%

set mm=%TIME:~3,2%

if "%time:~0,1%" == " " (set folderdate=0%time:~1,1%) ELSE set folderdate=%time:~0,2%

mkdir folderdate=%date:~6%%date:~3,2%%date:~0,2%_%folderdate%%time:~3,2%

copy \Makereport*.CSV \Makereport\%folderdate%\

cd %folderdate% REM -( 7zip in c:\batch) Path = c:\batch

7z a Retail.zip *.CSV -pRetailPassword

cd..

del *.csv

Answer 12

the expression %date:~p,n% returns n number of characters from position p in the date string.

if my system date string is Mon23/11/2015

the command %date:~1,3% returns the value Mon

the command %date:~10,4% returns the value 2015

and in conjunction with the md (or mkdir) command

the command md %date:~10,4%%date:~7,2%%date:~4,2% makes a directory named 20151123

likewise if your date string in in the format Monday, 23/Nov/2015

the command md %date:~16,4%%date:~12,3%%date:~9,2% makes a directory named 2015Nov23

If you accidentally return characters from the date string that are not allowed in folder names or use invalid values for p and n you will get an error. Additionally if you return values that include \ this may create a folder within a folder.

Answer 13

If your locale has date format "DDMMYYYY" you'll have to set it this way:

set datestr=%date:~-4,4%%date:~3,2%%date:~-10,2%
mkdir %datestr%

Answer 14

this is a more simpler solution.

@ECHO OFF
set name=%date%
echo %name%
mkdir %name% 

Answer 15

This works for me, try:

ECHO %DATE:~7,2%_%DATE:~4,2%_%DATE:~12,2%

Answer 16

You'll like this, change it so that it can suit your requirements.

mkdir today
Copy Desktop\test1\*.* today
setlocal enableextensions
set name=%DATE:/=_%
Rename "today" _OlddatabaseBackup_"%name%"

Answer 17

Thanks for the info all, very helpful. I needed something that could create "backup" folder as often as every minute in the same directory, as well as call on it later in the script. Here's what I came up with:

@ echo off

CD %userprofile%\desktop

SET Datefolder="%DATE:~4,2%-%DATE:~7,2%-%DATE:~12,2%_%time:~1,1%%time:~3,2%"

MD "%Datefolder%"

This gives me a folder on the currently logged on user's desktop named: mm-dd-yy_hmm (hour minute minute) ie: 07-28-15_719

Answer 18

I use the next code to make a file copy (e.g. test.txt) before replacing:

cd /d %~dp0
set backupDir=%date:~7,2%-%date:~-10,2%-%date:~-2,2%_%time:~0,2%.%time:~3,2%.%time:~6,2%
echo make dir %backupDir% ...
md "%backupDir%"
copy test.txt %backupDir%

It creates directory in format DD-MM-YY_HH.MM.SS and places text.txt there. Time with seconds in the name is necessary to create directory without additional verification.

Answer 19

https://stackoverflow.com/a/31789045/1010918 foxidrive's answer helped me get the folder with the date and time I wanted. I would like to share this method here since it worked great for me and I think it could help other people too, regardless of their locale.

rem The four lines below will give you reliable YY DD MM YYYY HH Min Sec MS variables in XP Pro and higher.

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%" & set "MS=%dt:~15,3%"

 set "dirname=%YYYY%-%MM%-%DD% %HH%-%Min%-%Sec%"

 :: remove echo here if you like
 echo "dirName"="%dirName%"

Answer 20

Use this batch script made by me:

@echo off
title Folder Creator
color b
setlocal enabledelayedexpansion
echo Enter the folder name, you can use these codes:
echo /t - Time (eg. 16:29)
echo /d - Date (eg. 17-02-19)
echo /a - Day (eg. 17)
echo /m - Month (eg. 02)
echo /y - Year (eg. 19)
echo /f - Full Year (eg. 2019)
echo.
set /p foldername=Folder Name:
set foldername=%foldername:/t=!time:~0,5!%
set foldername=%foldername:/d=!date:~0,2!-!date:~3,2!-!date:~8,2!%
set foldername=%foldername:/a=!date:~0,2!%
set foldername=%foldername:/m=!date:~3,2!%
set foldername=%foldername:/y=!date:~8,2!%
set foldername=%foldername:/f=!date:~6,4!%
md %foldername%

For example if you wanted to make a folder named the date in the DD-MM-YY format you would type "/d" but if you wanted to do that in the DD-MM-YYYY format you would type "/a-/m-/f".

Answer 21

this worked better for me,

@echo off    
set temp=%DATE:/=%
set dirname="%temp:~4,4%%temp:~2,2%%temp:~0,2%"
mkdir %dirname%

Answer 22

For YYYY.MM.DD format with HUN settings use following. It converts "2021. 02. 23." to "2021.02.23":

SET dirname="%date:~0,5%%date:~6,3%%date:~10,2%"
md %dirname%

Answer 23

G:

cd G:/app/

mkdir %date:~7,2%%date:~-10,2%%date:~-4,4% 

cd %date:~7,2%%date:~-10,2%%date:~-4,4% 

sqlplus sys/sys as sysdba @c:/new

Answer 24

I needed both the date and time and used:

mkdir %date%-%time:~0,2%.%time:~3,2%.%time:~6,2%

Which created a folder that looked like: 2018-10-23-17.18.34

The time had to be concatenated because it contained : which is not allowed on Windows.

Answer 25

setlocal enableextensions 
set name="%DATE:/=_%"
mkdir %name%

to create only one folder like "Tue 01_28_2020"