Typespecs for Arc.Ecto.changeset

Question

I am copying Arc.Ecto changeset example https://github.com/stavro/arc_ecto and I am not sure about the typespecs, I am trying with these but doesnt seem to work for dialyzer, it complains on |> cast_attachments(params, [:avatar])

@spec changeset(Ecto.Schema.t, map | :invalid) :: Changeset.t
def changeset(user, params \\ :invalid) do
  user
  |> cast(params, [:name])
  |> cast_attachments(params, [:avatar])
  |> validate_required([:name, :avatar])
end


> The pattern #{'__meta__':=_} can never match the type
> #{'__struct__':='Elixir.Ecto.Changeset', 'action':='delete' | 'insert' | 'nil' | 'replace' | 'update', 'changes':=#{atom()=>_},
> 'constraints':=[#{'constraint':=binary(), 'field':=atom(),
> 'match':='exact' | 'suffix', 'message':={binary(),[{atom(),_}]},
> 'type':='unique'}], 'data':='nil' | map(), 'empty_values':=_,
> 'errors':=[{atom(),{binary(),[{atom(),_}]}}], 'filters':=#{atom()=>_},
> 'params':='nil' | #{binary()=>_},
> 'prepare':=[fun((#{'__struct__':='Elixir.Ecto.Changeset',
> 'action':='delete' | 'insert' | 'nil' | 'replace' | 'update',
> 'changes':=map(), 'constraints':=[any()], _=>_}) ->
> #{'__struct__':='Elixir.Ecto.Changeset', 'action':='delete' | 'insert' | 'nil' | 'replace' | 'update', 'changes':=map(),
> 'constraints':=[any()], _=>_})], 'repo':=atom(), 'required':=[atom()],
> 'types':='nil' | #{atom()=>atom() | {'array',_} |
> {'embed',#{'__struct__':='Elixir.Ecto.Embedded', 'cardinality':='many'
> | 'one', 'field':=atom(), 'on_cast':='nil' | fun(),
> 'on_replace':='delete' | 'mark_as_invalid' | 'raise', 'owner':=atom(),
> 'related':=atom(), 'unique':=boolean()}} | {'in',_} | {'map',_}},
> 'valid?':=boolean(), 'validations':=[{atom(),_}]}

cast_attachments is a macro so I am not sure how to define a typespec for a macro since in it's source code hasnt any spec defined https://github.com/stavro/arc_ecto/blob/master/lib/arc_ecto/schema.ex

Answer 1

The error is caused by the case statement that checks the type of changeset_or_data. Since it is a macro, when dialyzer checks it after compiling, changeset_or_data has been defined in the calling module and so dialyzer knows what type it is, so one of the case statement clauses can never be reached. That's how I understand it...in any case moving the logic in the case statement out into functions seems to fix it:

  defmacro cast_attachments(changeset_or_data, params, allowed, options \\ []) do
    quote bind_quoted: [changeset_or_data: changeset_or_data,
                        params: params,
                        allowed: allowed,
                        options: options] do

      # If given a changeset, apply the changes to obtain the underlying data

      scope = do_apply_changes(changeset_or_data)

      # Cast supports both atom and string keys, ensure we're matching on both.
      allowed_param_keys = Enum.map(allowed, fn key ->
        case key do
          key when is_binary(key) -> key
          key when is_atom(key) -> Atom.to_string(key)
        end
      end)

      arc_params = case params do
        :invalid ->
          :invalid
        %{} ->
          params
          |> Arc.Ecto.Schema.convert_params_to_binary
          |> Map.take(allowed_param_keys)
          |> Enum.reduce([], fn
            # Don't wrap nil casts in the scope object
            {field, nil}, fields -> [{field, nil} | fields]

            # Allow casting Plug.Uploads
            {field, upload = %{__struct__: Plug.Upload}}, fields -> [{field, {upload, scope}} | fields]

            # If casting a binary (path), ensure we've explicitly allowed paths
            {field, path}, fields when is_binary(path) ->
              if Keyword.get(options, :allow_paths, false) do
                [{field, {path, scope}} | fields]
              else
                fields
              end
          end)
          |> Enum.into(%{})
      end

      cast(changeset_or_data, arc_params, allowed)
    end
  end

  def do_apply_changes(%Ecto.Changeset{} = changeset), do: Ecto.Changeset.apply_changes(changeset)
  def do_apply_changes(%{__meta__: _} = data), do: data

Note the new do_apply_changes function at the end

There's a fork here with a fix - https://github.com/madebymany/arc_ecto

I've put in a pull request to get it merged in - https://github.com/stavro/arc_ecto/pull/106