Is it Possible to Assign an Alias to a Function?

Question

I am writing a simple function, such as:

Function myFunction() As Variant
    'Some rules
End Function

For the above function, is it possible to assign an Alias like you can do with API calls?

Obviously this isn't the proper syntax, but you get the idea:

Function myFunction() Alias myFunc As Variant
    'Some rules
End Function

This would allow me to use either name:

Sub Test()
    Debug.Print myFunction
    Debug.Print myFunc
End Sub

Answer 1

I don't understand why you would need to have a VBA alias for an VBA function.

API Aliases are for referring to a function or other object in a DLL, if it's "given name" can't be used in the module that requires it.

Alias —— Indicates that the procedure being called has another name in the DLL. This is useful when the external procedure name is the same as a keyword. You can also use Alias when a DLL procedure has the same name as a public variable, constant, or any other procedure in the same scope. Alias is also useful if any characters in the DLL procedure name aren't allowed by the DLL naming convention. ^(Source)

...but to answer your question, sure you could create alternate name for a function, with only a slight modification to your code:

---

_{Your Function:}

Function myFunction() As Variant
    'Some rules
End Function

---

_{Assign an alternate name:}

Function myFunc() As Variant
   myFunc = myFunction
End Function

---

_{This would allow you to use either name:}

Sub Test()
    Debug.Print myFunction
    Debug.Print myFunc
End Sub

---

EDIT: "Can't remember UDF Names"

_{(When I said I didn't understand why you needed to do this, I assumed you didn't have a memory like mine! Now I understand your reasoning, giving multiple names to the same function!)}

What, haven't you memorized the name and syntax of all your custom VBA functions yet, on top of the 1000's of built-in functions, procedures and objects, and the seemingly unlimited list of property, method, and class names??

Me neither.

A feature that helps trigger my memory when coding in VBA is the List of Properties/Methods.

Start typing the name of a function or procedure and hit Ctrl+J, and you'll get a list of custom and built-in functions, methods, procedures, etc.**

I noticed that your sample function names all started with "my". That may have been just for illustrative purposes, however, a specific naming convention like that would also help by grouping your functions together in the Properties/Methods Dialog Box.

• See also: List of the 100+ VBA Keyboard Shortcuts _{(in case you forget the key combination!)}

---

More ways to remember How things work and what they're called:

You can also add a description to a UDF (User-Defined Function), which would appear when entering the function name on a worksheet:

See: How to put a 'Tooltip' on a user-defined function

---

Related:

• Add a Description to a User Defined Function in Excel (without VBA)

• VBA Productivity Tip: Procedure List

• The Quest for the Excel Custom Function Tooltip (C#)

---

Taking it a step further than the description, Registering the User-Defined Function allows not only the creation of a description for the function, but also detailed information about each of the function's parameters and their data types; you can even specify Shortcut Key(s), add links to custom "Help" files/pages, and even assign a Category for the UDF.

These extended attributes display in the Insert Function dialog , accessible by clicking the button to the left of the formula bar, or by hitting Shift+F3:

Excel doesn't have a built-in interface for editing parameter descriptions so VBA is required. Relevant documentation can be hard to locate.

---

Code & Info about Registering User-Defined Functions -:

• JKP: Registering a User Defined Function with Excel

• MSDN: Application.MacroOptions Method

• Add Description To A Custom VBA Function

---

Create a ribbon button to list VBA Procedures

I haven't tried this but I can see how it could be very handy, especially since it would be easy to customize further, perhaps with project-specific function lists and other information.

A button can be added to the ribbon, that when clicked displays a list of VBA procedures/functions, using XML and VBA to display a user form from a button. There's also an option to save the list of procedures to a text file.

You can already see the procedures in a workbook from the Macros button on the Developers tab. However, only parameter-less subroutines in modules and within a worksheet are displayed in the Macros dialog box. Functions and subroutines with parameters do not show up. The code described in this column displays all of the subroutines and functions in the workbook.

More information and complete code is available here.

---

VBA Code that writes VBA Code!?

By programmatically manipulating the VBA Editor (VBE), you can write code in VBA that reads or modifies other VBA projects, modules and procedures, and could be used to automate development-related tasks. This is called extensibility because it extends the editor -- you can use VBA code to create new VBA code. You can use these features to write custom procedures that create, change, or delete VBA modules and code procedures.

The amazing Chip Pearson has done it again, with detailed instructions and complete code available here for some of the fun things extensibility can do for you.

A partial list of code on Chip's page (which is here):

• Add/Delete/Rename a Module in a Project
• Add/Delete/Rename a Procedure in a Module
• Copy Modules Between Projects
• Create a New Procedure in a Code Module
• Create an Event Procedure
• Listing all Procedures in a Module
• Read a Procedure Declaration
• Search a Module For Text
• Fix Screen Flicker in the VBE
• Export a VBComponent to a Text File
• Test if a VBComponent Exists
• Determine the Workbook Associated with a VBProject
• Count lines of code in Module/Project/Component

The methods use the VBA Extensibility [library] (http://www.exceltoolset.com/setting-a-reference-to-the-vba-extensibility-library-by-code/) (reference) and require programmatic access to the VBA Project, which is a security setting in Excel's options. See Chip's page for more info.

Chip's pages also have great information and code available on Customizing Menus with VBA, which could have benefit in making the developer's own job easier.

---

A seemingly "forgotten" ability of VBA if functionality to control and even intercept built-in commands. This could also be used to benefit the developer (especially one with a poor memory!)... More information and examples from Microsoft here.

---

Answer 2

Simple VBA example (no classes)

As you are calling yourself TheNotSoGuru, try the following relative simple approach: Instead of an API like alias definition you would have to write your alias definitions in ONE user defined alias() function.

Calling test procedure

This shows you how to call your aliases using ONE user defined alias function; the first argument is your alias Name as string, other arguments define possible arguments of the original functions themselves:

Option Explicit     ' declaration head of your code module

Sub Test()
Debug.Print "0) Original Function", myFunction
Debug.Print "1) alias(""(myFunc1"")", alias("myFunc1")
Debug.Print "2) alias(""(myFunc2"")", alias("myFunc2")      ' too less arguments
Debug.Print "2) alias(""(myFunc2"",false)", alias("myFunc2", False)
End Sub

Example functions

The first example needs no argument; the second example demonstrates an incorrect as well as a correct alias function call - the original function attends the input of a boolean argument (True or False).

Function myFunction() As Variant
'Some rules
'...
'return result
 myFunction = "Result from myFunction"
End Function

Function myFunctionWithOneArgument(Optional ByVal b As Boolean = True) As String
'Some rules
If b Then
   myFunctionWithOneArgument = "result from myFunctionWithOneArgument " & "okay"
Else
   myFunctionWithOneArgument = "result from myFunctionWithOneArgument " & "without comment"
End If
End Function

=============== Example of an Alias() function

You are responsible to insert your alias definitions into the alias function. It allows you even to force inputs of the correct number of arguments by raising a 450 error "Wrong number of arguments ..." via error handling. If an error occurs a messagebox displays an error message.

Function alias(ByVal sFunc, Optional arg1, Optional arg2, Optional arg3)
On Error GoTo oops           ' error handler
Select Case sFunc & ""       ' check your own aliases as string values 
  Case "myFunc1", "1"        ' your alias Definition(s)
       alias = myFunction    ' return original function myFunction
  Case "myFunc2", "One"      ' see above
       ' defines if one argument is needed here:
       If IsMissing(arg1) Then Err.Raise (450)   ' too less arguments if arg1 is missing
       alias = myFunctionWithOneArgument(arg1)
  Case Else
       alias = "Unknown function alias " & sFunc
End Select
EverythingOkay:     Exit Function

oops:
MsgBox "Function: " & sFunc & vbNewLine & vbNewLine & _
       "Error No: " & Err.Number & vbNewLine & _
       Err.Description, vbExclamation, "Error - Wrong number of arguments"
Err.Clear
End Function

Answer 3

Searching Aliases via Similarity

A) Intro

Your Comment as of 1/22: "The issue is not that I necessarily want to call out the alias intentionally, it's an issue of forgetting what I may have named a function to begin with (ie. verifyRange vs verifyRng). If I knew I was calling the alias name to begin with then I wouldn't need to call the alias. But your solution does work and it was very well thought out."

Due to your example in above cited comment: As you slightly modified your initial question, I thought about an alternative solution and added it as an independant new answer:

► You could take some advantage of using a so called SoundEx search to group procedure names based on a phonetic algorithm.

Method: A Soundex code identifies a set of similar sounding terms, names or ... ► procedure names. If you combine this with a loop through a VBIDE list of all existing procedures/functions (don't forget to set a reference) you are able to get the most likely alias(es) listed.

Example result

1/1 Project(s): "VBAProject" (D:\Excel\test.xlsm)
**Project name: "VBAProject" ** (Host Project)
++SoundEx("verifyRange")="V616"
--   Found --  Procedure/Function name(s) ---------  ------------------
[Prc: Sub]     verifyRng   in Std Module modTest1    Line#: 2/[Body: 3]
[Prc: Sub]     verifyRange in Std Module modSortDict Line#: 6/[Body: 6]

Note: This method builds a condensed alphanumeric code based on the six phonetic classifications of human speech sounds (bilabial, labiodental, dental, alveolar, velar, and glottal), removing vocals and some occurences of 'H','W' and 'Y'; the code consists of the first capitalized letter and three following digits (filled with 0 if no more consonants found) . BTW origins date back to the late 1800's used for indexing American census records.

Links

Find the word which I closest to the particular string? http://www.creativyst.com/Doc/Articles/SoundEx1/SoundEx1.htm#JavaScriptCode https://en.wikipedia.org/wiki/Soundex

Soundex Example

To demonstrate the soundex coding, try the following example call with identical results:

Sub testSoundEx()
Dim i As Integer
Dim a()
a = Array("verifyRange", "verifyRng", "vrfRanges")
Debug.Print "Proc name", "SoundEx Code": Debug.Print String(50, "-")
For i = LBound(a) To UBound(a)
    Debug.Print a(i), SoundEx(a(i))
Next i
End Sub

SoundEx Function

Function SoundEx(ByVal s As String) As String
' Site:   https://stackoverflow.com/questions/19237795/find-the-word-which-i-closest-to-the-particular-string/19239560#19239560
' Source: Developed by Richard J. Yanco
' Method: follows the Soundex rules given at http://home.utah-inter.net/kinsearch/Soundex.html
Dim Result As String, c As String * 1
Dim Location As Integer
s = UCase(s)                ' use upper case
' First character must be a letter
If Len(Trim(s)) = 0 Then
   Exit Function
ElseIf Asc(Left(s, 1)) < 65 Or Asc(Left(s, 1)) > 90 Then
    SoundEx = ""
    Exit Function
Else
  ' (1) Convert to Soundex: letters to their appropriate digit,
    '             A,E,I,O,U,Y ("slash letters") to slashes
    '             H,W, and everything else to zero-length string
    Result = Left(s, 1)
    For Location = 2 To Len(s)
        Result = Result & Category(Mid(s, Location, 1))
    Next Location
  ' (2) Remove double letters
    Location = 2
    Do While Location < Len(Result)
        If Mid(Result, Location, 1) = Mid(Result, Location + 1, 1) Then
            Result = Left(Result, Location) & Mid(Result, Location + 2)
        Else
            Location = Location + 1
        End If
    Loop
   ' (3) If category of 1st letter equals 2nd character, remove 2nd character
    If Category(Left(Result, 1)) = Mid(Result, 2, 1) Then
        Result = Left(Result, 1) & Mid(Result, 3)
    End If
   ' (4) Remove slashes
    For Location = 2 To Len(Result)
        If Mid(Result, Location, 1) = "/" Then
            Result = Left(Result, Location - 1) & Mid(Result, Location + 1)
        End If
    Next
   ' (5) Trim or pad with zeroes as necessary
    Select Case Len(Result)
        Case 4
            SoundEx = Result
        Case Is < 4
            SoundEx = Result & String(4 - Len(Result), "0")
        Case Is > 4
            SoundEx = Left(Result, 4)
    End Select
End If
End Function

Helper function called by SoundEx()

This helper function returns a letter code based on phonetic classifications (see notes above):

Private Function Category(c) As String
'   Returns a Soundex code for a letter
Select Case True
    Case c Like "[AEIOUY]"
        Category = "/"
    Case c Like "[BPFV]"
        Category = "1"
    Case c Like "[CSKGJQXZ]"
        Category = "2"
    Case c Like "[DT]"
        Category = "3"
    Case c = "L"
        Category = "4"
    Case c Like "[MN]"
        Category = "5"
    Case c = "R"
        Category = "6"
    Case Else 'This includes H and W, spaces, punctuation, etc.
        Category = ""
End Select
End Function

► Solution to your issue - Example Call to get Functions by Alias

B) Memory issue or how to jog one's memory

You can use the following example call to search for procedure/function aliases via Syntax listProc {function name string}, e.g. listProc "verifyRange" and you get a condensed list of all found aliases in the Immediate Window of your Visual Basic Editor (VBE):

Sub Test()
listProc "verifyRange"  ' possibly gets verifyRange AND verifyRng via SoundEx "V616"
'listProc "verify"      ' possibly gets nothing, as SoundEx "V610" has no fourth consonant
'listProc                '[ displays ALL procedures without SoundEx Filter ]
End Sub

Note: Keep in mind that the SoundEx Code (e.g. "V616" for verifyRange) is limited to a length of four alphanumeric characters. If you are looking for "verify" only (= 3 consonants V+r+f), you would get "V610" instead without findings of "verifyRange" or "verifyRng" (V+r+f+r). In this case you should search for a pair of variants.

============================= Main procedure listProc =====================

Sub listProc(Optional ByVal sFuncName As String)
' Purpose: display procedures using a SoundEx Filter
' Call:   0 arguments or empty argument - ALL procedures without filter
'         1 argument (not empty)        - procedures found via SoundEx
' Note:   requires reference to Microsoft Visual Basic for Applications Extensibility 5.3
' Declare variables to access the macros in the workbook.
Dim VBAEditor      As VBIDE.VBE         ' VBE
Dim objProject     As VBIDE.VBProject   ' Projekt
Dim objComponent   As VBIDE.VBComponent ' Modul
Dim objCode        As VBIDE.CodeModule  ' Codeblock des Moduls
' Declare other miscellaneous variables.
Dim sProcName      As String
Dim sndx As String, sndx2 As String
Dim pk             As vbext_ProcKind       ' proc kind (Sub, Function, Get, Let)
Dim strPK          As String, sTyp As String
Dim iLine          As Integer, iBodyLine As Integer, iStartLine As Integer
Dim i              As Integer
Dim bShow          As Boolean             ' show procedure name
Dim bSoundEx       As Boolean
If Len(Trim(sFuncName)) > 0 Then bSoundEx = True  ' show alle procedures!
' ========================================
' Get the project details in the workbook.
' ========================================
  Set VBAEditor = Application.VBE

  Set objProject = VBAEditor.ActiveVBProject
' Set objProject = VBAEditor.VBProjects("MyProcject")   ' 1-based, project name or item number

 For i = 1 To VBAEditor.VBProjects.Count    ' show name, filename, buildfilename (DLL)
     Debug.Print i & "/" & _
                 VBAEditor.VBProjects.Count & " Project(s): """ & _
                 VBAEditor.VBProjects(i).Name & """ (" & VBAEditor.VBProjects(i).filename & ")"
 Next i
' get SoundEx of Function name
  sndx2 = SoundEx(sFuncName)
' ==================
' ? PROJECT NAME
' ==================
'   objProject.Type ...vbext_pt_HostProject 100 Host-Project
'                   ...vbext_pt_StandAlone  101 Standalone-Project
  Debug.Print "**Project name: """ & objProject.Name & """ ** (" & _
              IIf(objProject.Type = 100, "Host Project", "Standalone") & ")"
  If bSoundEx Then Debug.Print "++SoundEx(""" & sFuncName & """)=""" & sndx2 & """" & _
                               vbNewLine & "--   Found --  Procedure/Function name(s)"

' Iterate through each component (= Module) in the project.
For Each objComponent In objProject.VBComponents        ' alle MODULE
    ' Find the code module for the project (Codeblock in current component/=module).
      Set objCode = objComponent.CodeModule
      ' =============
      ' ? MODULE NAME
      ' =============
      If objCode.CountOfLines > 0 And Not bSoundEx Then
         Debug.Print " *** " & _
             sModType(objComponent.Type) & " ** " & objComponent.Name & " ** "
      End If
  ' Scan through the code module, looking for procedures.
  ' Durch alle Codezeilen des jeweiligen Moduls gehen
    iLine = 1
    Do While iLine < objCode.CountOfLines               ' alle Zeilen durchackern (1/End ...)

      ' =================
      ' Get Procedurename                               ' !! SETZT AUTOMATISCH >> pk << !!
      ' =================
        sProcName = objCode.ProcOfLine(iLine, pk)       ' jede nächste Zeile auf Prozedurbeginn checken

        If sProcName <> "" Then                         ' ohne Declaration head
            ' -----------------
            ' Found a procedure
            ' -----------------
            ' a) Get its details, and ...
              strPK = pk                                 ' 0-Prc|1-Let/2-Set/3-Get Werte abfangen !!!
           '' iStartLine = objCode.ProcStartLine(sProcName, strPK)  ' here = iLine !!
              iBodyLine = objCode.ProcBodyLine(sProcName, strPK)    ' Zeilennr mit Sub/Function/L/S/Get
              sTyp = sPrcType(objCode.Lines(iBodyLine, 1))          ' Sub|Fct|Prp
            ' b) Check Soundex
              If bSoundEx Then
                 sndx = SoundEx(sProcName)
                 If sndx = sndx2 Or UCase(sProcName) = UCase(sFuncName) Then
                    bShow = True
                 Else
                    bShow = False
                 End If
              Else
                 bShow = True
              End If
              ' ==============
              ' c) ? PROC NAME
              ' --------------
              If bShow Then
                 Debug.Print "    " & "[" & sPK(strPK) & ": " & sTyp & "] " & _
                          sProcName & IIf(bSoundEx, " in " & sModType(objComponent.Type) & " " & objComponent.Name, "") & vbTab, _
                          "Line#: " & iLine & "/[Body: " & iBodyLine & "]"
              End If
            ' -------------------------------------------
            ' d) Skip to the end of the procedure !
            '    => Add line count to current line number
            ' -------------------------------------------
              iLine = iLine + objCode.ProcCountLines(sProcName, pk)
        Else
            ' This line has no procedure, so => go to the next line.
            iLine = iLine + 1
        End If
    Loop

Next objComponent

' Clean up and exit.
  Set objCode = Nothing
  Set objComponent = Nothing
  Set objProject = Nothing


End Sub

3 Helper Functions to the Main procedure listProc

These helper functions return additional information to procedures and module:

Function sPK(ByVal prockind As Long) As String
' Purpose: returns short description of procedure kind (cf ProcOfLine arguments)
Dim a(): a = Array("Prc", "Let", "Set", "Get")
sPK = a(prockind)
End Function

Function sPrcType(ByVal sLine As String) As String
' Purpose: returns procedure type abbreviation
If InStr(sLine, "Sub ") > 0 Then
   sPrcType = "Sub"     ' sub
ElseIf InStr(sLine, "Function ") > 0 Then
   sPrcType = "Fct"     ' function
Else
    sPrcType = "Prp"    ' property (Let/Set/Get)
End If
End Function

Function sModType(ByVal moduletype As Integer) As String
' Purpose: returns abbreviated module type description
Select Case moduletype
   Case 100
     sModType = "Tab Module"
   Case 1
     sModType = "Std Module"
   Case 2
     sModType = "CLS Module"
   Case 3
     sModType = "Frm Module"
   Case Else
     sModType = "?"
 End Select
End Function