Batch file execution with closing automatically after a specific period of time

Question

@echo off
color 0a
title welcome 
echo welcome batch


echo #     # ####### #        #####  ####### #     # #######     
echo #  #  # #       #       #     # #     # ##   ## #          
echo #  #  # #       #       #       #     # # # # # #            
echo #  #  # #####   #       #       #     # #  #  # #####       
echo #  #  # #       #       #       #     # #     # #           
echo #  #  # #       #       #     # #     # #     # #           
echo  ## ##  ####### #######  #####  ####### #     # #######       
pause  >nul

I want to run it during startup, and close it automatically by itself after a specific period of time.

@JosefZ thanks, mate...really appreciate your help. One more help ! how to set a specific resolution for my batch file window? — Piyush Basak, Dec 09 '17 at 16:41
I know almost nothing about `cmd` window _resolution_ however you could **resize** it using something like `mode con: cols=60 lines=12`. — JosefZ, Dec 09 '17 at 22:20
Possible duplicate of [How to sleep for 5 seconds in Windows's Command Prompt? (or DOS)](https://stackoverflow.com/questions/1672338/how-to-sleep-for-5-seconds-in-windowss-command-prompt-or-dos) — phuclv, Dec 10 '17 at 16:04

Hackoo · Accepted Answer · 2017-12-10T09:10:39.270

Here is an example of a welcome screen with playing music in background using vbscript :

You can change the variable PeriodTime as you needs here is set to (120 seconds = 2 minutes) as example

@echo off
Title Welcome Screen with DJ Buzz Radio by Hackoo 2017
mode con cols=64 lines=35 & color 0A
REM You can change the variable PeriodTime as you needs here is set to (120 seconds = 2 minutes) as example
Set "PeriodTime=120"
Call :Stop_Radio
Call :Play_DJ_Buzz_Radio
echo(
cls
:::
:::      __   __  _______  ___      ___      _______ 
:::     |  | |  ||       ||   |    |   |    |       |
:::     |  |_|  ||    ___||   |    |   |    |   _   |
:::     |       ||   |___ |   |    |   |    |  | |  |
:::     |       ||    ___||   |___ |   |___ |  |_|  |
:::     |   _   ||   |___ |       ||       ||       |
:::     |__| |__||_______||_______||_______||_______|
:::
:::              _ _,---._
:::           ,-','       `-.___
:::          /-;'               `._
:::         /\/          ._   _,'o \
:::        ( /\       _,--'\,','"`. )
:::         |\      ,'o     \'    //\
:::         |      \        /   ,--'""`-.
:::         :       \_    _/ ,-'         `-._
:::          \        `--'  /                )
:::           `.  \`._    ,'     ________,','
:::             .--`     ,'  ,--` __\___,;'
:::              \`.,-- ,' ,`_)--'  /`.,'
:::               \( ;  | | )      (`-/
:::                 `--'| |)       |-/
:::                   | | |        | |
:::                   | | |,.,-.   | |_
:::                   | `./ /   )---`  )
:::                  _|  /    ,',   ,-'
:::                 ,'|_(    /-<._,' |--,
:::                 |    `--'---.     \/ \
:::                 |          / \    /\  \
:::               ,-^---._     |  \  /  \  \
:::            ,-'        \----'   \/    \--`.
:::           /            \              \   \
:::

for /f "delims=: tokens=*" %%A in ('findstr /b ::: "%~f0"') do @echo(%%A

>NUL TIMEOUT /T %PeriodTime% /NOBREAK & Call :Stop_Radio & exit
::**************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set vbsfile=%temp%\DJBuzzRadio.vbs
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play %URL% %vbsfile%
Start %vbsfile%
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo  Dim Sound
echo  Set Sound = CreateObject("WMPlayer.OCX"^)
echo  Sound.URL = URL
echo  Sound.settings.volume = 100
echo  Sound.Controls.play
echo  do while Sound.currentmedia.duration = 0
echo   wscript.sleep 100
echo  loop
echo  wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
::**************************************************************

Batch file execution with closing automatically after a specific period of time

1 Answers1