How to code Power Set in Lisp R5RS

Question

I'm new to functional programming and I have no idea how to code this in Lisp. For example, for a given power set such as (1 2 3), how do I code it in a way to make it: (WITHOUT using Lambda functions) ( () (1) (2) (3) (1 2 3) )

So far, I have:

(define  (powerSet lis)
  (if (null? lis) '(()))
 )

(define (APPENDS lis1 lis2)
   (cond
   ((null? lis1) lis2)
        (else (cons (car lis1)
            (APPENDS (cdr lis1) lis2)))
  )
)

Which just returns the empty set, or nothing.

EDIT:

Thank you so much Chris! That made so much sense. The second variation (without the append-map function) works well. However, if you input (powerset'(1 2 3 4)), it gives you:

(() (1) (2) (1 2) (3) (1 3) (2 3) (1 2 3) (4) (1 4) (2 4) (1 2 4) (3 4) (1 3 4) (2 3 4) (1 2 3 4))

Is there anyway for me to make it look like:

(() (1) (2) (3) (4) (1 2) (1 3) (1 4) (2 3) (2 4) (3 4) (1 2 3) (1 2 4) (1 3 4) (2 3 4) (1 2 3 4))

Thanks so much!

Answer 1

All user-defined functions are lambda (or case-lambda) expressions, including the powerset function you're defining. There is no way to avoid it. However, you can hide the lambda identifier by using internal definitions (it's still a lambda behind the scenes!^†).

With this in mind, here's an implementation (requires Racket or SRFI 1):

(define (powerset lst)
  (define (make-pair x)
    (list x (cons (car lst) x)))
  (if (null? lst)
      '(())
      (append-map make-pair (powerset (cdr lst)))))

If you're trying to avoid append-map or higher-order functions in general, you could jump through a few hoops to do the same thing:

(define (powerset lst)
  (define (inner next)
    (if (null? next)
        '()
        (cons (car next)
              (cons (cons (car lst) (car next))
                    (inner (cdr next))))))
  (if (null? lst)
      '(())
      (inner (powerset (cdr lst)))))

---

^† An expression like

(define (foo bar)
  baz)

is actually expanded into the following equivalent expression:

(define foo
  (lambda (bar)
    baz))