Output to .CSV?

Question

I have a batch file that checks in an item and checks it out, It works fine but Is it possible to make a VBS that would turn my .txt file to a .csv so it is easier to read or to make the batch file directly output it to a .csv file?

My issue is I need to convert the .txt/.log to a .csv.

The Batch file

@echo off
title Checkin
color 0a

SETLOCAL EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
  set "DEL=%%a"
)


cls
:home
cls
call :ColorText 0b "---------------------------------------"
echo.
call :ColorText 74 "-               Welcome               -"
echo.
call :ColorText 0b "---------------------------------------"
echo.
call :ColorText 0a "        Ready, Awaiting Scan...        "
echo.
set /p scan=
cls
call :ColorText 0a "-            Please Wait...           -"
echo.
echo %time% %date% >>%scan%.log
echo %scan% %date% %time% >>master.xml
ping localhost -n 3 >nul
echo.
call :ColorText 0a "-               Success!              -"
echo.
ping localhost -n 2 >nul
goto :home


:ColorText
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1

The Output:

 9:27:14.94 Tue 10/20/2015 
 9:27:22.65 Tue 10/20/2015 
 9:28:37.00 Tue 10/20/2015

I need the Spreadsheet to look like:

    Date  |  Time
 DDMMYYYY | HHMMSS

1. CSV would look like `DDMMYYYY,HHMMSS`; 2. `%DATE%` & `%TIME%` return locale-dependent date/time format, so you'll need `wmic OS GET LocalDateTime`... — aschipfl, Oct 20 '15 at 20:41
check [this](http://stackoverflow.com/a/19799236/388389) for see few ways for getting date/time format independent from regional settings. — npocmaka, Oct 20 '15 at 20:54
why does everybody use a pipe symbol as delimter in **c**omma **s**eparated **v**alue files? — Stephan, Oct 20 '15 at 21:06
UPDATE: I need the output to NOT be a .log file and BE a .CSV. Sorry for the confusion. — Display Word, Oct 20 '15 at 21:25
@Stephan we use the pipe exclusively in my line of work. We can pretty much guarantee with 100% certainty that it will never be a value within our clients data. We also have another client that uses a ~ as their delimiter. — Squashman, Oct 20 '15 at 22:10
I simply used it to show the edge of a cell like in excel, not as a delimiter — Display Word, Oct 20 '15 at 22:13
@DisplayWord your file is ultimately an ascii text file. You can use any file extension you want! — Squashman, Oct 21 '15 at 02:31
Thanks I found out if I just put %time%,%date% >>logs.CSV it will make excel read it! Thanks all for your assistance! — Display Word, Oct 21 '15 at 02:35
@DisplayWord, so everyone just wasted their time showing you how to format the DATE and TIME in the format you described in your question. — Squashman, Oct 21 '15 at 14:28

SachaDee · Answer 1 · 2015-10-20T22:50:36.270

1

@echo off

for /f "delims=." %%a in ('wmic os get LocalDateTime^| findstr [0-9]') do set "$all=%%a"

>>scan.csv echo %$all:~0,8%;%$all:~8%

edited Oct 20 '15 at 22:50

answered Oct 20 '15 at 21:03

SachaDee

8,843
2
18
29

Squashman · Answer 2 · 2015-10-21T02:33:54.217

0

Formats the time & date which is regional dependent so adjust accordingly and outputs to a file.

FOR /F "tokens=1-3 delims=:" %%G IN ("%TIME: =0%") DO set oTime=%%G%%H%%I

FOR /F "tokens=2-4 delims= /" %%G IN ("%DATE%") DO set oDate=%%G%%H%%I

echo %oDate%,%oTime% >>scan.csv

edited Oct 21 '15 at 02:33

answered Oct 20 '15 at 20:42

Squashman

11,987
5
23
33

score -1 · Accepted Answer · answered Oct 28 '15 at 18:10

-1

%time%,%date% >>logs.CSV will add it to a .csv file which will open in execel

answered Oct 28 '15 at 18:10

Display Word

96
1
3
10

Output to .CSV?

3 Answers3