How can I sort a Perl hash on values and order the keys correspondingly (in two arrays maybe)?

Question

In Perl, I want to sort the keys of a hash by value, numerically:

{
  five => 5
  ten => 10
  one => 1
  four => 4
}

producing two arrays:

(1,4,5,10) and (one, four, five, ten)

And then I want to normalize the values array such that the numbers are sequential:

(1,2,3,4)

How do I do this?

score 61 · Accepted Answer · answered Jun 05 '12 at 16:29

61

First sort the keys by the associated value. Then get the values (e.g. by using a hash slice).

my @keys = sort { $h{$a} <=> $h{$b} } keys(%h);
my @vals = @h{@keys};

Or if you have a hash reference.

my @keys = sort { $h->{$a} <=> $h->{$b} } keys(%$h);
my @vals = @{$h}{@keys};

answered Jun 05 '12 at 16:29

ikegami

322,729
15
228
466

2

That was easy. Sometimes it's difficult to come up with those nice shortcuts. Thanks ikegami. – Gogi Jun 05 '12 at 19:14
You can see more info in [sort function in Perl](http://stackoverflow.com/questions/6454744/sort-function-in-perl/6454804#6454804) – yc_yuy Feb 24 '14 at 06:57

score 7 · Answer 2 · answered Jul 15 '13 at 00:10

How do I sort a hash (optionally by value instead of key)?

To sort a hash, start with the keys. In this example, we give the list of keys to the sort function which then compares them ASCIIbetically (which might be affected by your locale settings). The output list has the keys in ASCIIbetical order. Once we have the keys, we can go through them to create a report which lists the keys in ASCIIbetical order.

my @keys = sort { $a cmp $b } keys %hash;

foreach my $key ( @keys ) {
    printf "%-20s %6d\n", $key, $hash{$key};
}

We could get more fancy in the sort() block though. Instead of comparing the keys, we can compute a value with them and use that value as the comparison.

For instance, to make our report order case-insensitive, we use lc to lowercase the keys before comparing them:

my @keys = sort { lc $a cmp lc $b } keys %hash;

Note: if the computation is expensive or the hash has many elements, you may want to look at the Schwartzian Transform to cache the computation results.

If we want to sort by the hash value instead, we use the hash key to look it up. We still get out a list of keys, but this time they are ordered by their value.

my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash;

From there we can get more complex. If the hash values are the same, we can provide a secondary sort on the hash key.

my @keys = sort {
$hash{$a} <=> $hash{$b}
or
"\L$a" cmp "\L$b"
} keys %hash;

Nit: `lc($a) cmp lc($b)`, which you also wrote as `"\L$a" cmp "\L$b"`, won't always do the right thing. You want `fc($a) cmp fc($b)` (`"\F$a" cmp "\F$b"`). Available since 5.16. — ikegami, Jul 15 '13 at 13:27

score 4 · Answer 3 · edited Mar 12 '21 at 04:39

4

Please see the Perl FAQ entry titled "How do I sort a hash (optionally by value instead of key)".

You can also use perldoc -q to search the FAQ locally on your machine, as in perldoc -q sort, which is how I found your answer.

edited Mar 12 '21 at 04:39

Peter Mortensen

28,342
21
95
123

answered Jun 05 '12 at 16:47

Andy Lester

81,480
12
93
144

score 3 · Answer 4 · answered Jun 05 '12 at 16:37

3

my ( @nums, @words );
do { push @nums,  shift @$_; 
     push @words, shift @$_; 
   }
    foreach sort { $a->[0] <=> $b->[0] } 
            map  { [ $h->{ $_ }, $_ ] } keys %$h
   ;

answered Jun 05 '12 at 16:37

Axeman

29,194
2
42
98

@Moni, it works quite well, written the way it is. if you need `%h` then it's just `keys %h` and `$h{ $_ }` in the map. – Axeman Jun 05 '12 at 23:58
An explanation would be in order. E.g., what is the idea? – Peter Mortensen Mar 12 '21 at 04:39

How can I sort a Perl hash on values and order the keys correspondingly (in two arrays maybe)?

4 Answers4

Linked

Related