**Disclaimer**: This is another long comment reporting on the attempt to attack the problem numerically.

Instead of parametrizing the 6 segments of the unit stick as $$(u_1,u_2-u_1,u_3-u_2,u_4-u_3,u_5-u_4,1-u_5)$$
where $(u_1,u_2,u_3,u_4,u_5)$ are order statistics of the uniform distribution with pdf
$$
f_U(u_1,u_2,u_3,u_4,u_5) = 5! \cdot \left[0<u_1<u_2<u_3<u_4<u_5<1 \right]
$$
I am using a different parametrization:
$$
(1-w_1, w_1 (1-w_2), w_1 w_2 (1-w_3), w_1 w_2 w_3 (1-w_4), w_1 w_2 w_3 w_4 (1-w_5), w_1 w_2 w_3 w_4 w_5 )
$$
It is easy to solve for $\{w_k\}$ in terms of $\{u_k\}$:
$$
w_1 = 1-u_1, w_2 = \frac{1-u_2}{1-u_1}, w_3 = \frac{1-u_3}{1-u_2}, w_4 = \frac{1-u_4}{1-u_3}, w_5 = \frac{1-u_5}{1-u_4}
$$
which allows to find their induced measure:
$$
f_W(w_1,w_2,w_3,w_4,w_5) = (5 w_1^4 [0<w_1<1]) \cdot (4 w_2^3 [0<w_2<1]) \cdot (3 w_3^2 [0<w_3<1] ) \cdot (2 w_4 [0<w_4<1]) \cdot ( [0<w_5<1] )
$$
meaning that $w_k$ are independent random variable with different power distributions on the unit interval.

This parametrization is friendlier to numerical integration routines.

We then proceed much like @achille-hui . Here is *Mathematica* code I ran:

```
TriangleInequalities[{a_, b_, c_}] :=
a < b + c && b < a + c && c < a + b
FacialTetrahedron[{x_, y_, z_, xb_, yb_, zb_}] :=
TriangleInequalities[{x, y, zb}] &&
TriangleInequalities[{x, yb, z}] &&
TriangleInequalities[{xb, y, z}] &&
TriangleInequalities[{xb, yb, zb}]
TetrahedraSextupleQ[{x_, y_, z_, xb_, yb_, zb_}] :=
FacialTetrahedron[{x, y, z, xb, yb, zb}] &&
Det[{{0, x^2, y^2, z^2, 1}, {x^2, 0, zb^2, yb^2, 1}, {y^2, zb^2, 0,
xb^2, 1}, {z^2, yb^2, xb^2, 0, 1}, {1, 1, 1, 1, 0}}] > 0
```

We now build the event that one can form a tetrahedron out of 6 pieces the unit stick is divided into. The following takes a while to compute.

```
event2 = Assuming[
0 < w1 < 1 && 0 < w2 < 1 && 0 < w3 < 1 && 0 < w4 < 1 && 0 < w5 < 1,
Simplify[
Apply[Or,
Simplify[TetrahedraSextupleQ[#]] & /@
Permutations[{(1 - w1),
w1 (1 - w2), w1 w2 (1 - w3), w1 w2 w3 (1 - w4),
w1 w2 w3 w4 (1 - w5), w1 w2 w3 w4 w5 }]]]];
```

Therefore I saved the resulting predicate in paste-bin. Here is how to import it:

```
event2 = ToExpression[
Import["http://pastebin.com/raw.php?i=399MDkGQ", "Text"],
InputForm];
```

We now define a compiled filter function to decide if a random vector fires the event.

```
cfFunc2 = With[{ee = event2},
Compile[{{arg, _Real, 1}}, Block[{w1, w2, w3, w4, w5},
{w1, w2, w3, w4, w5} = arg;
If[ee, 1, 0]], RuntimeAttributes -> Listable]];
```

The function above allows to efficiently run the Monte-Carlo simulation. Here is the simulation that takes some 4.7hours:

```
In[3]:= Block[{sample, tot = 0, suc = 0},
While[suc <= 10^9,
sample =
RandomVariate[
ProductDistribution[PowerDistribution[1, 5],
PowerDistribution[1, 4], PowerDistribution[1, 3],
PowerDistribution[1, 2], UniformDistribution[]], 3*10^8];
tot += Length[sample];
suc += Total[cfFunc2[sample]];
];
{suc, tot}
] // AbsoluteTiming
Out[3]= {16994.098510, {1018403735, 15600000000}}
```

Entailing the following $(1-10^{-8})/2$-level confidence interval:

```
In[38]:= Block[{suc = 1018403735, tot = 15600000000},
PlusMinus[N[suc/tot],
Sqrt[2.] InverseErfc[10^-8] Sqrt[
With[{p = suc/tot}, p (1 - p)/tot]]]]
Out[38]= 0.0652823 \[PlusMinus] 0.0000113341
```

The advantage of the $w$-parametrization is that Cartesian quadrature rules can be applied. Using the fact that $w_k = 2^{-1/k}$ for $1 \leqslant k \leqslant 5$ furnishes a tetrahedral splitting:

```
In[160]:= event2 /. {w1 -> (1/2)^(1/5), w2 -> (1/2)^(1/4),
w3 -> (1/2)^(1/3), w4 -> (1/2)^(1/2), w5 -> 1/2`}
Out[160]= True
```

we can help numerical quadrature algorithm to find a sample point inside the region of interest. So with enough time at hand it should be possible to get a more precise quadrature answer:

```
AbsoluteTiming[
prob = NIntegrate[
f[w1, w2, w3, w4, w5], {w1, 0, (1/2)^(1/5), 1}, {w2,
0, (1/2)^(1/4), 1}, {w3, 0, (1/2)^(1/3), 1}, {w4, 0, (1/2)^(1/2),
1}, {w5, 0, 1/2, 1},
Method -> {"CartesianRule", "SymbolicProcessing" -> 0},
MaxRecursion -> 14]]
```

However, after some 20 hours, this integration command is still running...
I will post the answer once the evaluation is complete.